Combat Profile Improvements for Warlords SimulationCraft

Given that I don’t have beta access to Warlords of Draenor, all of my rotation testing has to be done in a theorycrafting tool and not in-game. I also have to trust those theorycrafting tools are modeling things correctly as I can not log into the beta to verify them myself.

That preamble aside, last night I decided to build the WoD version of Simulationcraft to see if I could tweak the combat action priority list for an improvement, and to get some more insight into some mechanics.

The first thing I did was changed the priority list’s handling of Revealing Strike. The default priority list still uses Mists of Pandaria’s priority of only casting Revealing Strike to maintain the debuff. Considering Revealing Strike does 96% weapon damage for 40 energy and Sinister Strike does 102% weapon damage for 50 energy, Revealing Strike deals 17% more damage-per-energy than Sinister Strike. Sinister Strike also deals 1.2 combo points per 50 energy, compared to Revealing Strike’s 1 combo point per 40 energy. This means Revealing Strike deals roughly 4.1% more combo points per energy spent as well.

Intuition says that with deep insight at 50%, we want to get to deep insight as fast as possible to maximize its uptime (mechanics/damage phases aside). Since Revealing Strike does not advance Bandit’s Guile, we want to minimize its use while ramping up, but once in deep insight, it’s all about what does more damage. Given that Revealing Strike does more damage per energy and generates more combo points per energy than Sinister Strike, we want to switch to using Revealing Strike as the primary combo point generator during deep insight.

So I modified the default action list to stop using sinister strike during deep insight and to also hold deep insight for adrenaline rush if there is less than 10 seconds left on its cooldown and we are 1 sinister strike from deep insight, to hold deep insight for adrenaline rush. Note that modifying the action list to hold for killing spree is WAY more complicated because you can’t push to deep insight during the spree like you can with adrenaline rush, it’s a minor inefficiency in the adrenaline rush handling (it casts adrenaline rush, THEN sinister strike to push deep insight).

Some other changes I made to the default profile were to change the dagger offhand to match the main hand. Main Gauche and Killing Spree are significant sources of damage and favor a slow offhand. I switched Venom Rush to Shadow Reflection (just to see), and found it a gain right out of the door, so I tried tweaking the action list to line Shadow Reflection up with cooldowns. As it turns out, it’s a gain to do this even up to 20 seconds because Shadow Reflection does not copy poisons or autoattacks (and yellow attacks outside of cooldowns for combat are pretty anemic). The other (probably controversial) change that I made was dropping Anticipation for Marked for Death. Even in Mists of Pandaria these two are close, but combo point generation is high in Siege of Orgrimmar gear where energy is overflowing. During the energy-starved start of an expansion, having free combo points can be pretty valuable. Turns out Marked for Death is about 1.5% ahead.

So, here is the default in-combat priority list for combat at level 100:

# Executed every time the actor is available.

actions=potion,name=draenic_agility,if=buff.bloodlust.react|target.time_to_die<40
actions+=/kick
actions+=/use_item,slot=trinket2
actions+=/blood_fury
actions+=/berserking
actions+=/arcane_torrent,if=energy<60
actions+=/blade_flurry,if=(active_enemies>=2&!buff.blade_flurry.up)|(active_enemies<2&buff.blade_flurry.up)
actions+=/shadow_reflection
actions+=/ambush
actions+=/killing_spree,if=energy<50
actions+=/adrenaline_rush,if=energy<35
actions+=/slice_and_dice,if=buff.slice_and_dice.remains<2|(buff.slice_and_dice.remains<15&buff.bandits_guile.stack=11&combo_points>=4)
actions+=/marked_for_death,if=combo_points<=1&dot.revealing_strike.ticking
actions+=/run_action_list,name=generator,if=combo_points<5|(talent.anticipation.enabled&anticipation_charges<=4&!dot.revealing_strike.ticking)
actions+=/run_action_list,name=finisher,if=!talent.anticipation.enabled|buff.deep_insight.up|anticipation_charges>=4
actions+=/run_action_list,name=generator,if=energy>60|buff.deep_insight.down|buff.deep_insight.remains>5-combo_points


# Combo point generators
actions.generator=revealing_strike,if=ticks_remain<2
actions.generator+=/sinister_strike

# Combo point finishers
actions.finisher=crimson_tempest,if=active_enemies>7&dot.crimson_tempest_dot.ticks_remain<=1
actions.finisher+=/eviscerate

Here is my modified action list (the last run_action_list line was removed because it really doesn’t ever do anything).

# Executed every time the actor is available.

actions=potion,name=draenic_agility,if=buff.bloodlust.react|target.time_to_die<40
actions+=/kick
actions+=/use_item,slot=trinket2
actions+=/blood_fury
actions+=/berserking
actions+=/arcane_torrent,if=energy<60
actions+=/blade_flurry,if=(active_enemies>=2&!buff.blade_flurry.up)|(active_enemies<2&buff.blade_flurry.up)
actions+=/shadow_reflection,if=(cooldown.killing_spree.remains<10&combo_points>3)|buff.adrenaline_rush.up
actions+=/ambush
actions+=/killing_spree,if=energy<50&(!talent.shadow_reflection.enabled|cooldown.shadow_reflection.remains>30|buff.shadow_reflection.remains>3)
actions+=/adrenaline_rush,if=energy<35
actions+=/slice_and_dice,if=buff.slice_and_dice.remains<2|(buff.slice_and_dice.remains<15&buff.bandits_guile.stack=11&combo_points>=4)
actions+=/marked_for_death,if=combo_points<=1&dot.revealing_strike.ticking&(!talent.shadow_reflection.enabled|buff.shadow_reflection.up|cooldown.shadow_reflection.remains>30)
actions+=/run_action_list,name=generator,if=combo_points<5|(talent.anticipation.enabled&anticipation_charges<=4&buff.deep_insight.down)
actions+=/run_action_list,name=finisher,if=!talent.anticipation.enabled|buff.deep_insight.up|anticipation_charges>=4

# Combo point generators
actions.generator=revealing_strike,if=ticks_remain<2|buff.deep_insight.up|(buff.bandits_guile.stack=11&cooldown.adrenaline_rush.remains<10)
actions.generator+=/sinister_strike

# Combo point finishers
actions.finisher=crimson_tempest,if=active_enemies>7&dot.crimson_tempest_dot.ticks_remain<=1
actions.finisher+=/eviscerate

And for the results, the default profile with a dagger offhand, anticipation, and venom rush managed 23,813 dps +/- 14.17. My tweaked profile (with sword offhand, marked for death, shadow reflection, and the modified priority list) comes out to 26,284 +/- 16.66 dps. 10% is a pretty significant improvement without changing item level. The main conclusion we can draw from this is that the action lists have a ways to go yet (I’m not claiming even this is optimal, so I encourage anyone to improve upon it). Given that the beta is in tuning passes, I implore theorycrafters to try to improve upon the subtlety and assassination lists.

Advertisements

3 responses to “Combat Profile Improvements for Warlords SimulationCraft”

  1. Fiska says :

    I asked if switching to Revealing Strike during Deep Insight is intended, and Celestalon confirms it’s not. Getting fixed in the next build.

  2. Falkien says :

    Great article!

Leave a Reply

Fill in your details below or click an icon to log in:

WordPress.com Logo

You are commenting using your WordPress.com account. Log Out / Change )

Twitter picture

You are commenting using your Twitter account. Log Out / Change )

Facebook photo

You are commenting using your Facebook account. Log Out / Change )

Google+ photo

You are commenting using your Google+ account. Log Out / Change )

Connecting to %s

%d bloggers like this: